kill(all)$
f : 4.00e6$    /*Frequency*/
u_0pwotand : 1$ /*Voltage at PZT neglecting dielectric loss*/
d_zSmaxs : 1.71E-10$ /*Normal deflection amplitude (0-peak) at u_0pwotand*/
R_otand : 4.98946517574$  /*Resistance from PZT neglecting dielectric loss*/
X : -19.15754420601$  /*Reactance from PZT*/
tandelta : 0.195$ /*dielectric loss*/
R_tand : abs(tandelta*X); /*Part of resistance from PZT considering dielectric loss*/
u_PZT0ps : u_0pwotand*abs((R_otand+%i*X+R_tand)/(R_otand+%i*X))$ /*Voltage amplitude at actuator 0-peak considering dielectric loss*/
d_zSmax0pg1V : d_zSmaxs/u_PZT0ps*1; /*Normal deflection amplitude (0-peak) at u_PZT0p=1 V*/
emod : 2.1e11$ /*Young's modulus*/
pz : 0.27$ /*Poisson's ratio*/
rho : 7850$ /*Density*/
b_IDT : 26.38e-3$ /*width of IDT structure*/
omega : 2*%pi*f$    /*angular speed*/
lambda : emod*pz/(1+pz)/(1-2*pz)$ /*Lamé constants*/
my : emod/(2+2*pz)$
kl : omega*(rho/(lambda+2*my))^(1/2)$ /*wavenumbers*/
kt : omega*(rho/my)^(1/2)$
eta : (0.87+1.12*pz)/(1+pz)$
k : kt/eta$
q : (k^2-kl^2)^(1/2)$
s : (k^2-kt^2)^(1/2)$
A : d_zSmax0pg1V/(q*(1-2*k^2/(k^2+s^2)))$   /*Amplitude for Rayleigh equation, determined by deflection*/
vx : -A*k*omega*(exp(-q*z)-2*q*s/(k^2+s^2)*exp(-s*z))*cos(k*x)$ /*tangential particle velocity for time t=0*/
vz : A*q*omega*(exp(-q*z)-2*k^2/(k^2+s^2)*exp(-s*z))*sin(k*x)$ /*normal particle velocity for time t=0*/
P_AOW : float(rho*f*b_IDT*integrate(integrate(vx^2+vz^2,x,0,2*%pi/k),z,0,inf)); /*wave power determined by particle velocity*/
P_el : 0.5*realpart(1^2/2/(R_otand+R_tand+%i*X)); /*electrical Power, determined by electr. impedance (factor 0.5, as only one out of two Rayleigh waves is considered)*/
p : P_AOW/P_el; /*efficiency of actuator*/;